Números Felizes e Sucessões Associadas:
Digressões com o Maple

Delfim F. M. Torres
delfim@mat.ua.pt

Departamento de Matemática
Universidade de Aveiro
3810-193 Aveiro, Portugal
http://www.mat.ua.pt/delfim

Aceite para publicação na revista Educação e Matemática da Associação de Professores de Matemática, Nº 77, Março/Abril 2004.

Ver também: Delfim F. M. Torres, Números Felizes e Sucessões de Smarandache: Digressões com o Maple,
Smarandache Notions Journal, Vol. 14, 2004, pp. 119-123:
http://www.mat.ua.pt/delfim/delfim/artigos/TorresSNJ14.pdf

Resumo: Dando jus à matemática experimental, mostramos como o Maple pode ser usado na investigação matemática de algumas questões actualmente sem resposta na Teoria dos Números. A tese defendida é que os alunos de um curso de Matemática podem facilmente usar o computador como um lugar onde se excita e exercita a imaginação.

Introdução

Albert Einstein é conhecido por ter dito que "a imaginação é mais importante que o conhecimento". Se assim é, porquê esperar pelo mestrado ou doutoramento
para começar a enfrentar problemas em aberto? Não é a criatividade prerrogativa dos mais novos? Em [6] mostrei como com muito pouco conhecimento
é possível debruçar-mo-nos sobre algumas questões actualmente sem resposta na Teoria de Computação. Aqui, e a propósito do ano 2003 ter sido escolhido pela APM como o ano da Matemática e Tecnologia , vou procurar mostrar como o computador e um ambiente moderno de computação algébrica, como seja o Maple, podem ser excelentes auxiliares na abordagem a "quebra-cabeças" que a matemática dos números actualmente nos coloca. A nossa tese é a de que para compreender e lidar confortavelmente com conceitos e métodos matemáticos, é necessário fazer matemática. Tradicionalmente, isso implicava o uso de cabeça, papel e lápis. Nos dias de hoje junta-se mais um ingrediente: o computador e respectivo software. O software de apoio à Matemática pode ser classificado em duas grandes famílias: os de carácter específico (e.g. Cabri-géomètre, Cinderella, Geometer's Sketchpad, etc) e os de carácter universal (e.g. Maple, Mathematica, Maxima, Axiom, etc). Os Sistemas Universais são ferramentas muito poderosas, extremamente úteis para matemáticos, cientistas e professores. A minha escolha do sistema Maple prende-se com o facto de ser este o programa informático actualmente usado na cadeira de Computadores no Ensino da Matemática , no Departamento de Matemática da Universidade de Aveiro. Os meus alunos são prova viva de que basta um semestre de "tecnologias na educação matemática", para nos podermos aventurar por "mares ainda não navegados". O leitor que queira aprender sobre o Maple poderá começar por consultar os sites de Computadores no Ensino da Matemática , disponíveis a partir da minha home page: http://www.mat.ua.pt/delfim . Os que não tiverem acesso ao sistema comercial Maple, mas quiserem fazer as suas próprias experiências e descobertas, podem recorrer a um dos muitos sistemas de computação algébrica disponibilizados em regime livre. Aconselho o Maxima. Versões do Maxima, para Linux e Windows, com manuais de utilização, podem ser encontrados em http://maxima.sourceforge.net

Números felizes

Um número é feliz se somando os quadrados dos seus algarismos e iterando o processo for possível chegar ao número 1. Por exemplo:
7^2 = 49, 4^2 + 9^2 = 97, 9^2 + 7^2 = 130, 1^2 + 3^2 + 0^2 = 10, 1^2 + 0^2 = 1,
pelo que 7 é um número feliz. De modo mais formal. Seja n \in N um número natural com representação decimal n = d_k ... d_0, 0 <= d_i <= 9 (i = 0,...,k), e denotemos por sigma(n) a soma dos quadrados dos dígitos decimais de n: sigma(n) = \sum_{i=0}^{k} (d_i)^2. Dizemos que n é um número feliz se existir um

r \in N tal que (sigma o ... o sigma)(n) = 1 (composição reptida r vezes). Para o exemplo acima, vemos que 7 é um número feliz após 5 iterações (r=5):
sigma(7) = 49, sigma(49) = 97, sigma(97) = 130, sigma(130) = 10, sigma(10) = 1
Um exemplo de um número que não é feliz é o 2:
sigma(2) = 4, sigma(4) = 16, sigma(16) = 37, sigma(37) = 58, sigma(58) = 89, sigma(89) = 145, sigma(145) = 42, sigma(42) = 20, sigma(20) = 4 ...
É possível mostrar ( vide [5]) que n \in N não é feliz se, e somente se, (sigma o ... o sigma)(n) = 4 para um certo número de iterações.

Vamos definir em Maple a função característica Booleana dos números felizes. Começamos por definir a função digitos que nos devolve
a sequência de dígitos de um dado número n. Para isso recorremos às funções Maple iquo e irem que nos dão, respectivamente, o quociente e o resto da divisão inteira.

> digitos := n -> seq(iquo(irem(n,10^i),10^(i-1)),i=1..length(n)):

> digitos(12345);

A função sigma é agora facilmente construída

> sigma := n -> add(i^2,i=digitos(n)):

> sigma(24);

O processo de composição da função sigma é obtido usando o operador @ doMaple:

> s := (n,r) -> seq((sigma@@i)(n),i=1..r):

> s(7,5);

> s(2,9);

Para automatizarmos o processo de decisão se um número é feliz ou não, recorremos a alguma programação. O seguinte procedimento deve ser claro.

> feliz := proc(n)

> local L, v:

> L := {}:

> v := sigma(n):

> while (not (member(v,L) or v=1)) do

> L := L union {v}:

> v := sigma(v):

> end do:

> if (v = 1) then true else false end if:

> end proc:

Podemos agora questionar o sistema Maple acerca da felicidade de um determinado número.

> feliz(7);

> feliz(2);

A lista de todos os números felizes até 100 é dada por

> select(feliz,[$1..100]);

Concluímos então que existem 20 números felizes de entre os primeiros 100 naturais

> nops(select(feliz,[$1..100]));

Existem 143 números felizes não superiores a 1000;
1442 não superiores a 10000;

e 3038 não superiores a 20000:

> select(feliz,[$1..1000]);

> nops(%);

> select(feliz,[$1..10000]);

> nops(%);

> select(feliz,[$1..20000]);

> nops(%);

Estas últimas experiências com o Maple permitem-nos formular a seguinte conjectura.
Conjectura. Cerca de um sétimo de todos os números são felizes.

Uma questão interessante é estudar números felizes consecutivos. De entre os primeiros 1442 números felizes podemos encontrar
238 pares de números felizes consecutivos (o mais pequeno é o (31,32));

> felizDezMil := select(feliz,[$1..10000]):

> select(i->member(i,felizDezMil) and member(i+1,felizDezMil),felizDezMil);

> nops(%);

onze ternos de números felizes consecutivos, o mais pequeno dos quais é o (1880,1881,1882);

> select(i->member(i,felizDezMil) and member(i+1,felizDezMil) and member(i+2,felizDezMil),felizDezMil);

dois quaternos de números felizes consecutivos, o mais pequeno dos quais é o (7839,7840,7841,7842);

> select(i->member(i,felizDezMil) and member(i+1,felizDezMil) and member(i+2,felizDezMil) and member(i+3,felizDezMil),felizDezMil);

e nenhuma sequência de cinco números felizes consecutivos.

> select(i->member(i,felizDezMil) and member(i+1,felizDezMil) and member(i+2,felizDezMil) and member(i+3,felizDezMil) and member(i+4,felizDezMil),felizDezMil);

Sabe-se que a primeira sequência de cinco números felizes consecutivos começa com o 44488.

> feliz(44488) and feliz(44489) and feliz(44490) and feliz(44491) and feliz(44492);

É também conhecida uma sequência de 7 números felizes consecutivos, que começa com o número 7899999999999959999999996 ( vide [7]).

Uma outra linha de investigação interessante ( vide [2]) surge quando analisamos o número de iterações necessárias até chegarmos a 1. Ao número de iterações chamamos altura . A altura de 7 é, como vimos, 5. O número 356 também é feliz, mas precisa de 6 iterações (tem altura 6). É muito fácil alterar o nosso procedimento feliz para obtermos a altura de um número feliz.

> altura := proc(n)

> local L, v, a:

> L := {}:

> v := n:

> a := 0:

> while (not (member(v,L) or v=1)) do

> L := L union {v}:

> v := sigma(v):

> a := a + 1:

> end do:

> if (v = 1) then a else false end if:

> end proc:

Agora já podemos comprovar o que afirmámos acima:

> altura(7);

> altura(356);

As alturas dos primeiros 20 números felizes são facilmente obtidas:

> seq(altura(i),i=select(feliz,[$1..100]));

Esta experiência põe em evidência um facto curioso: os números felizes precisam de relativamente poucas iterações para alcançar a unidade. De facto, se calcularmos a altura de todos os números felizes até 3789 * 10^{973}-2, verificamos que a altura máxima é de 7. O seguinte procedimento permite-nos mostrar que 78999 é o primeiro número feliz com altura 7.

> primeiro := proc(alt)

> local i;

> for i while altura(i) <> alt do od:

> return(i);

> end proc:

> primeiro(7);

Os primeiros números felizes com altura 0, 1, 2, 3, 4, 5, 6 e 7 são, respectivamente:

> seq(primeiro(i),i=0..7);

O primeiro número com altura 8 é o 3789 * 10^{973}-1 ( vide [2]). Este número tem 977 dígitos:

> length(3789 * 10^973 - 1);

O conceito de número feliz é facilmente generalizável se considerarmos a soma dos dígitos elevados ao cubo ou a potências superiores. Alterando a definição
da função sigma , do modo óbvio, convidamos o leitor a repetir as nossas experiências e descobertas para os números felizes cúbicos, ...

Sucessões de Smarandache

Dada uma sucessão de inteiros {u_n}, a correspondente sucessão de Smarandache {s_n} é definida por concatenação de inteiros como se segue:
s_1 = u_1, s_2 = u_1 u_2, ..., s_n = u_1 ... u_n, ...

Estamos interessados na sucessão de Smarandache associada aos números felizes. Os primeiros elementos desta sucessão são:
1, 17, 1710, 171013, 17101319, 1710131923, 171013192328, 17101319232831,
Começamos por implementar a concatenação de inteiros em Maple.

> conc := (a,b) -> a*10^length(b)+b:

> conc(12,345);

Formando a lista dos números felizes até um certo n, e usando a função conc acima definida, a correspondente sucessão de Smarandache é facilmente obtida.

> sh := proc(n)

> local L, R, i:

> L := select(feliz,[$1..n]):

> R := array(1..nops(L),L):

> for i from 2 by 1 while i <= nops(L) do

> R[i]:=conc(R[i-1],L[i]):

> end do:

> return(R):

> end proc:

Como

> select(feliz,[$1..31]);

os primeiros 8 valores da sucessão de Smarandache são então

> print(sh(31));

Existem muitas questões em aberto associadas à sucessão de Smarandache dos números felizes ( vide [4]). Umas dizem respeito à existência de números primos na sucessão; outras à existência de números felizes. Façamos agora alguma investigação a este respeito. Usando o Maple é fácil concluir que de entre os primeiros 143 termos da sucessão de Smarandache dos números felizes, apenas 3 são primos.

> primos := select(isprime,sh(1000)):

> seq(primos[i],i=1..143);

> nops([%]);

> primos[2], primos[5];

> primos[43];

> length(%);

Apenas são conhecidos estes números primos na sucessão de Smarandache dos números felizes. Permanece por esclarecer se eles serão ou não em número finito
( vide [3]).

Existem 31 números felizes de entre os primeiros 143 termos da sucessão de Smarandache dos números felizes:

> shFelizes := select(feliz,sh(1000));

> nops([seq(shFelizes[i],i=1..143)]);

Os números são o s_1, s_{11}, s_{14}, s_{30}, s_{31}, s_{35}, s_{48}, s_{52}, s_{58}, s_{62}, s_{67}, s_{69}, s_{71}, s_{76}, s_{77}, s_{78}, s_{82}, s_{83}, s_{85}, s_{98}, s_{104}, s_{108}, s_{110}, s_{114}, s_{115}, s_{117}, s_{118}, s_{119}, s_{122}, s_{139} e s_{140}. Repare-se que s_{140} tem 399 dígitos:

> length(shFelizes[140]);

Muito existe por esclarecer relativamente à existência de números felizes consecutivos na sucessão de Smarandache dos números felizes. Olhando para os resultados anteriores vemos que o par mais pequeno de números felizes consecutivos é o (s_{30},s_{31}); enquanto o terno mais pequeno é o (s_{76}, s_{77}, s_{78}). Quantos termos consecutivos são possíveis? É capaz de encontrar exemplos, digamos, de seis números felizes consecutivos?
Estas e outras questões estão em aberto ( vide [3]). Ferramentas como o Maple são boas auxiliares neste tipo de investigações ( vide [1]).
Fico à espera de algumas respostas da sua parte.
delfim@mat.ua.pt

Referências

[1] P. D. F. Gouveia and D. F. M. Torres, Smarandache Sequences: Explorations and Discoveries with a Computer Algebra System , Smarandache Notions Journal, Vol. 14, 2004, pp. 5-22 (see online version at http://www.mat.ua.pt/delfim/delfim/artigos/arxivSmarandache/0312014.pdf ).

[2] H. G. Grundman and E. A. Teeple, Heights of Happy Numbers and Cubic Happy Numbers, The Fibonacci Quarterly, Vol. 41, Nº 4, Agosto de 2003,
pp. 301-306.

[3] S. S. Gupta, Smarandache sequence of happy numbers , Smarandache Notions Journal, Vol. 13, no. 1-3, 2002 (see online version at http://www.shyamsundergupta.com/shappy.htm ).

[4] R. K. Guy, Unsolved problems in number theory , Second edition, Springer, New York, 1994.

[5] R. Honsberger, Ingenuity in Mathematics , The Mathematical Association of America, 1970.

[6] D. F. M. Torres, O Computador Matemático de Post , Boletim da Sociedade Portuguesa de Matemática, Nº 46, Abril de 2002, pp. 81-94.

[7] D. W. Wilson, Sequence A055629 (Jun 05 2000) in the On-Line Encyclopedia of Integer Sequences, http://www.research.att.com/~njas/sequences